Stock Analysis

The script below illustrates how a stock analysis dashboard can be composed with Envision.


read "/sample/Lokad_Items.tsv" as Items
read "/sample/Lokad_Orders.tsv" as Orders
read "/sample/Lokad_PurchaseOrders.tsv" as PO

show label "Stock value analysis" a1f1 tomato
oend := max(Orders.Date)

// Default currency, and currency conversions
when date >= oend - 365
  currency := mode(Orders.Currency)
Orders.NetAmount = forex(Orders.NetAmount, Orders.Currency, currency, Orders.Date)
PO.NetAmount = forex(PO.NetAmount, PO.Currency, currency, PO.Date)

// FIFO inventory valuation
PO.Fifo = fifo(StockOnHand + StockOnOrder, PO.Date, PO.Quantity)
Fifo = sum(PO.Fifo * PO.NetAmount / PO.Quantity)

PO.Fifo2 = fifo(StockOnOrder, PO.Date, PO.Quantity)
Fifo2 = sum(PO.Fifo2 * PO.NetAmount / PO.Quantity)

// FIFO inventory age
StockAge = sum(PO.Fifo * (oend - PO.Date)) /. sum(PO.Fifo)

// Top row of KPIs
show table "Stock on hand (FIFO)" a2 unit:" \{currency}" with sum(Fifo - Fifo2)
show table "Stock on order (FIFO)" c2 unit:" \{currency}" with sum(Fifo2)
show table "Items in stock" e2 with count(StockOnHand + StockOnOrder > 0)
when date > oend - 31
where sum(Orders.Quantity) by Id > 0
  show table "Items unstocked" f2 with sum(1)

// Stock by category and supplier
show barchart "Stock by category" a3c5 tomato with
  group by Category
  order by sum(Fifo) desc

show barchart "Stock by supplier" d3f5 tomato unit:" \{currency}" with
  group by Supplier
  order by sum(Fifo) desc

// Most heavy stocked items, most aged stock items
show table "Most heavy stock items" a6c8 with
  StockOnHand as "On Hand"
  StockOnOrder as "On Order"
  Fifo as "Value" unit:" \{currency}"
  order by Fifo desc

show table "Most aged stock items" d6f8 with
  StockOnHand as "On Hand"
  Fifo as "Value" unit:" \{currency}"
  StockAge as "Age (days)"
  order by Fifo * StockAge desc // mixing age and value on purpose

// Most pressured stock items
D = sum(Orders.Quantity) when date >= oend - 13 * 7
where StockOnHand + StockOnOrder <= 0 & D > 0
  show table "Most demanded unstocked items" a9c11 tomato with
    D as "Units sold last quarter"
    order by D desc

V = sum(Orders.NetAmount) when date >= oend - 13 * 7
where sum(V) by Supplier > 0
  show barchart "Stock age by supplier { days}" d9f11 tomato with
    sum(V * StockAge) / max(1, sum(V))
    group by Supplier
    order by sum(V * StockAge) / max(1, sum(V)) desc